Raccolta latte

Problema

La centrale del latte è un consorzio di produttori di latte e si occupa di raccogliere, trasformare e distribuire prodotti caseari.

I produttori sono dislocati in vari punti della zona (nella mappa indicati in rosso con lettera P), come pure gli stabilimenti di trasformazione (nella mappa indicati in blu con lettera S).

Si vuole organizzare la movimentazione del latte in modo tale da minimizzare i costi di trasferimento dai produttori agli stabilimenti di trasformazione.

Si vuole trovare il costo medio di trasferimento unitario da considerare nella definizione del prezzo di vendita del latte

Analisi

L'analisi del problema ha portato a una possibile formulazione di modello da utilizzare per risolvere il problema.

Si ricorre ad alcune ipotesi semplificative che permettano di considerare sono gli aspetti rilevanti del problema, e alla raccolta dei dati che si ritengono utili nella descrizione del modello.

Si tralasciano le unità di misura assicurando che i valori numerici siano omogenei.

Sono note le quantità massime giornaliere di latte prodotto per i singoli produttori

Sono note le quantità massime giornaliere di latte lavorabile dai singoli stabilimenti

Sono noti i costi unitari per il trasferimento del latte da ogni produttore a ogni stabilimento.

Si suppone che tutto il latte prodotto venga lavorato

Dati

La raccolta delle informazioni ha portato ai seguenti dati che descrivono il modello matematico che sarà utilizzato per formulare una possibile soluzione del problema posto.

Capacità produttive dei produttori

P1	600
P2	500
P3	800
P4	400

Capacità di lavorazione degli stabilimenti

S1	200
S2	350
S3	800
S4	950

Costi di trasporto unitari da ogni produttore a ogni stabilimento

	S1	S2	S3	S4
P1	4	6	8	5
P2	6	2	3	4
P3	4	6	4	3
P4	1	4	7	4

Modello grafico

Costruiamo una rappresentazione grafica del modello

Rappresentiamo i produttori e gli stabilimenti come nodi di un grafo

Gli archi rappresentano i possibili trasferimenti

Modello matematico

La ricerca della soluzione ottimale per il problema parte dalla formulazione di un modello matematico del problema

Si individuano le variabili decisionali, su cui si va ad agire, e i parametri del modello.

Più il modello sarà accurato del descrivere il problema e più la soluzione trovata fornirà indicazioni attendibili sulla soluzione ottima del problema reale.

Indichiamo con $x_{ij}$ la quantità di latte da produttore j a stabilimento j

Indichiamo con $c_{ij}$ il costo del trasferimento da produttore j a stabilimento j

Indichiamo con $p_{i}$ la capacità produttiva del produttore i

Indichiamo con $s_{j}$ la capacità trasformativa dello stabilimento j

Le variabili decisionali sono le quantità $x_{ij}$ di latte trasferite da ogni produttore a ogni stabilimento

I vincoli da rispettare nel formulare la soluzione sono i seguenti

Per ogni produttore le quantità inviate agli stabilimenti devono eguagliare la quantità prodotta

$\sum_{j} x_{ij} = p_{i}$

Per ogni stabilimento le quantità arrivate dai produttori devono eguagliare la capacità di lavorazione

$\sum_{i} x_{ij} = s_{j}$

La funzione obiettivo descrive numericamente la bontà della soluzione proposta

Il problema richiede di trovare le quantità da trasferire da ogni produttore a ogni stabilimento per rendere minimo il costo totale di trasferimento

$min \sum_{i, j} c_{ij} \cdot x_{ij}$

Programma matematico

Una volta formulato il modello matematico, si può procedere alla risoluzione.

In questo caso si è scritto un programma per un risolutore specializzato in programmazione lineare.

param M; /* numero produttori */

set I := 1..M;

param N; /* numero stabilimenti */

set J := 1..N;

param c{i in I, j in J};

param p{i in I};

param s{j in J};

var x{i in I, j in J}, >= 0;

s.t. Produzione {i in I}:

sum{j in J} x[i,j] = p[i];

s.t. Lavorato {j in J}:

sum{i in I} x[i,j] = s[j];

minimize Z:

sum{i in I, j in J} c[i,j] * x[i,j];

solve;

data;

param M := 4;

param N := 4;

param c : 1 2 3 4 :=

1 4 6 8 5

2 6 2 3 4

3 4 6 4 3

4 1 4 7 4

;

param p :=

1 600

2 500

3 800

4 400

;

param s :=

1 200

2 350

3 800

4 950

;

end;

Risultati

Il risolutore ha fornito i seguenti risultati

Produttore Stabilimento Quantità

1 4 600

2 2 150

2 3 350

3 3 450

3 4 350

4 1 200

4 2 200

Costo totale

8200

Costo unitario 3,56

Analisi della soluzione

La soluzione fornita è la migliore possibile per il modello formulato.

Meno il modello rispecchia la realtà e meno attendibile sarà la soluzione trovata.

Ad esempio i dati che descrivono la produzione o la lavorazione potrebbero non essere stati stimati con sufficiente precisione, oppure ci possono essere aspetti del problema che non erano stati presi in considerazione.

L'abilità dell'esperto ottimizzatore sta nel formulare un modello accurato, nel valutare l'attendibilità e la sensibilità della soluzione proposta, ed eventualmente riformulare il modello per adattarlo alle nuove informazioni acquisite.